Za korekce češtiny dekuji: MELSOFTovi, Silliconovi, Martinu Lukáškovi a NOSTALCOMPovi
Když začínám blbnout z 8bitů tak se chodím léčit mezi otaku.
ÚVOD | Novinky | 8 Bitů | Příslušenství | Drobnosti | TTL | Kontakt
SAPI-1 | ONDRA | PMI-80 | PMD-85 | klony PMD-85 | klony SM50/40 | PETR | PLAN-80A | IQ151 | TNS | FK-1 | HVĚZDA
ZPS | Technické prostředky | Programové vybavení | Dokumentace
Upravena verze s doplněnými komentáři dle "SOUŘADNICOVÝ ZAPISOVAČ ŘÍZENÝ MIKROPROCESOREM" z AR MIKROELEKTONIKA/90 str. 22-24
;PROGRAM OBSLUHY MINIGRAFU PRES DESKU DPP-1
;V SYSTEMU SAPI-1 ZPS-2
;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
;ODLISNA ADRESACE JE PRO PRIPAD POUZITI DESKY
;PORTU SPOLECNE S OMLADANIM KZD-1 NEBO SP-210
;VERSE V.1-MGF V EPROM 1800-1FFF
;150289
MINIG EQU 1800H
START EQU MINIG+0F0H
STAR1 EQU MINIG+4FDH
PORT EQU 033H ;CWR
PORT2 EQU PORT-2 ;PORT B
INC EQU 0C0B1H ;SLUZBA MONITORU
IODEF EQU 11EH ;SLUZBA MONITORU
NEXT EQU 139H ;NAVRAT DO MONITORU
ZAZN EQU 0FFD0H ;ZAZNAMNIK V RAM
; EQU MINIG-1 ;VERSE V RAM
RMTOP EQU ZAZN-1 ;VERSE V EPROM
TABSK EQU 1D40H ;ADRESA TABULKY ZNAKU ;NIZSI BYTE 40H
VIRAM EQU 3800H ;POCATEK VIDEORAM
KVRAM EQU 3EH ;HORNI BYTE KONCE VIDEORAM
;TABULKA SKOKU:
ASEG
ORG MINIG
NOP
NOP
NOP
CALL ORGB0 ;INICIALIZACE PORTU
EXIT: JMP NEXT
CALL TEST ;SPUSTI TEST Z MONITORU
JMP EXIT
CALL COPY1 ;COPY Z MONITORU
JMP EXIT
CALL SYST0 ;NASTAVI MINIGRAF JAKO
JMP EXIT ;SYST.TISKARNU
JMP SYSTB ;DTTO Z BASICU
NOP
NOP
NOP
JMP RAMTP ;SPUSTENI Z BASICU
NOP
NOP
NOP
JMP COPYB ;COPY Z BASICU
JMP MOVA ;MOVA
JMP MOVAB ;MOVA Z BASICU
JMP VECTA ;VECTA
JMP VECTB ;VECTA Z BASICU
JMP POINA ;POINTA
JMP POINB ;POINTA Z BASICU
JMP MOVR ;MOVR
JMP MOVRB ;MOVR Z BASICU
JMP VECTR ;VECTR
JMP VECTC ;VECTR Z BASICU
JMP POINR ;POINTR
JMP PONRB ;POINTR Z BASICU
JMP SPEED ;NASTAVI SPEED
JMP WRTEB ;TISK RETEZCE
JMP ZNAK ;TISK ZNAKU
JMP NASXX ;NASTAVENI SIZE XX A YY
JMP NASYX ;NASTAVENI SIZE XY A YX
JMP NWIDE ;NASTAVENI WIDE
JMP NNARR ;NASTAVENI NARROW
ORG START
SYSTB: PUSH H
POP B
JMP SYST
SYST0: NOP
NOP
NOP
NOP
NOP
NOP
SYST: CALL ORG1
MVI A,001H ;NAST.ASCII
STA REZIM
MVI C,00DH
LXI D,TISK
CALL IODEF
RET
TISK: PUSH B ;TEST NA 0AH
PUSH D
PUSH H
MOV A,C
CPI 0AH
JNZ NO0A
LHLD NOPY
MOV B,H
MOV C,L
LXI D,0
CALL MOVA
JMP NAVR
NO0A: CPI 0DH ;TEST NA 0DH
JNZ NO0D
LHLD SIYY
MVI B,8
PUSH H
XCHG
POP H
POCET: DAD D
DAD D
DCR B
JNZ POCET
MOV A,H
CMA
MOV H,A
MOV A,L
CMA
MOV L,A
INX H
MOV B,H
MOV C,L
LXI D,0
CALL MOVR
NAVR: POP H
POP D
POP B
RET
NO0D: CALL ZNAK
POP H
POP D
POP B
RET
NASXX: SHLD SIYY
XCHG
SHLD SIXX
RET
NASYX: SHLD SIYX
XCHG
SHLD SIXY
RET
NWIDE: MVI A,0
STA WIDE
RET
NNARR: MVI A,80H
STA WIDE
RET
MOVAB: PUSH H
POP B
MOVA: CALL PEN0
JMP ABSO
VECTB: PUSH H
POP B
VECTA: CALL PEN1
JMP ABSO
POINB: PUSH H
POP B
POINA: CALL PEN0
CALL ABSO
JMP SK06
MOVRB: PUSH H
POP B
MOVR: CALL PEN0
JMP RELA
VECTC: PUSH H
POP B
VECTR: CALL PEN1
JMP RELA
PONRB: PUSH H
POP B
POINR: CALL PEN0
CALL RELA
JMP SK06
SK06: CALL PEN1
JMP PEN0
SPEED: ADI 008H
STA 0017CH
RET
ORGB0: LXI H,0
LXI D,0
RAMTP: PUSH D ;NASTAVI RAMTOP
MVI C,8
LXI D,RMTOP
CALL IODEF
POP D
ORGB: MVI A,99H ;PORT [A],[C] DOVNITR, [B] VEN
OUT PORT
PUSH H
POP B
JMP ORG1
ORG1: MVI A,14H ;NASTAV SI RYCHLOST
STA SPED
STA P185
PUSH D ;SCHOVEJ ZADANE X,Y
PUSH B
MVI A,1
STA SPEN ;ZVEDNI PERO
LXI B,8
MOV D,B
MOV E,C
CALL MOVR ;PAR KROKU DOLEVA NAHORU
MVI A,0BH ;UPRAV RYCHLOST
STA SPED
LXI H,06A4H ;MAXIMALNI X
SHLD STPX
LXI H,0FE70H;Y PO ZALOZENI PAPIRU
SHLD STPY
POP B
PUSH B ;OBNOV Y - PRESUN NA ZADANE Y
LXI D,0 ;OKAMZITE A NA 0 DO X
CALL MOVA
POP B ;OBNOV Y
PUSH B
LXI D,50H ;KOUSEK DOPRAVA
CALL MOVA
XRA A
STA STPX
POP B
POP D
CALL MOVA
NAST: MVI A,0AH
STA P185
NSIZE: LXI H,3 ;STANDARTNI VELIKOST ZNAKU
SHLD SIXX
SHLD SIYY
MVI L,0
SHLD SIXY
SHLD SIYX
SHLD REZIM ;REZIM
MVI A,80H
STA WIDE ;MEZERA
RET
RELA: LHLD STPX ;K X PRICTI RELATIVNI DX
DAD D ;= NOVA X
XCHG
LHLD STPY ;TOTEZ S Y
DAD B
MOV B,H
MOV C,L ;A MUZES UDELAT ABS. PRESUN
ABSO: LHLD STPX ;DE = ZADAVE XZ
XCHG ;HL = SKUTECNE X
SHLD STPX ;DE <=> HL ; X <=> XZ
SHLD NOPX ;A ULOZ NA NOVOU POZ. TISKU
CALL SMR ;ZJISTI SMER POSUVU PRO X
PUSH H ;SCHOVEJ ROZDIL X A XZ
PUSH B ;SCHOVEJ YZ
MOV C,A ;C = SMER POSUVU
POP D ;DE = PREDESLE BC TJ. ZADANA YZ
LHLD STPY ;HL = SKUTECNA Y
XCHG ;DE <=> HL ; Y <=> YZ
SHLD STPY
SHLD NOPY ;ULOZ
CALL SMR ;A ZJISTI SMER PRO Y
RLC
RLC
RLC
RLC ;DO VYSICH 4 BITU A
MOV B,A
ORA C ;SLOZ S C
STA DIRE ;<= SMER DO Y A DO X
POP D ;OBNOV ROZDIL X A XZ
RZ ;JSOU JI OBA POVUNY 0 VRAT SE
MOV A,L
SUB E
MOV A,H
SBB D ;TEST, KTERY POSUN JE VETSI
MOV A,C ;A = SMER POSUNU A
JC DALX ;SKOC PROTOZE (YZ-Y)<(XZ-X)
XCHG ;DE <=> HL ; (XZ-X) <=> (YZ-Z)
MOV A,B ;A = SMER DO Y
DALX: STA DIR1
SHLD DIFF
LXI H,14H ;MALE POZASTAVENI
CALL ZPOZ0
MVI A,29H
STA ACCE ;ROZBEHOVA RYCHLOST
MOV B,D ;BC = ROZDIL
MOV C,E
XRA A
SUB E
MOV L,A
MVI A,0
SBB D
MOV H,A ;HL = DE * -1
XRA A
MOV A,D
RAR
MOV D,A
MOV A,E
RAR
MOV E,A ;DE = DE / 2
ABS1: PUSH H ;SCHOVEJ HL A DE
PUSH D
XCHG ;DE <=> HL
MOV H,B
MOV L,C ;HL = BC
DAD H
DCX H ;HL = HL * 2 - 1
DAD D ;HL = HL + DE
LXI H,ACCE
JNC ABS2 ;JE-LI HL >= 0 SKOC
LDA P185
CMP M
JZ ABS2
DCR M
ABS2: MVI A,28H
SUB M
SUB C
MVI A,0
SBB B
JC ABS3
INR M
ABS3: LHLD DIFF
POP D
DAD D
XCHG
POP H
PUSH H
DAD D
LDA DIR1
JNC ABS4
XCHG
LDA DIRE
ABS4: PUSH D
CALL ELEM
DCX B
MOV A,B
ORA C
POP D
POP H
JNZ ABS1
RET
SMR: MOV A,L ;VRATI A = 0 PRO SKUT. = ZADANE
; A = 1 PRO SKUT. < ZADANE
; A = F PRO SKUT. > ZADANE
SUB E
MOV L,A ;L = L - E
MOV A,H
SBB D
MOV H,A ;H = H - D - PREDCHOZI ZNAM.
DAD H ;HL = HL * 2
JNC SMVL ;-> JE-LI HL KLADNE
XRA A ;ZAPORNE - PREVED NA KLADNE
SUB L
MOV L,A
MVI A,0
SBB H
MOV H,A ;HL = -1 * HL
MVI A,0FH ;PRIZNAK A NAVRAT
RET
SMVL: MOV A,H
ORA L
RZ ;JE-LI HL = 0 VRAT SE
MVI A,01H
RET ;JINAK PRIZNAK A NAVRAT
WRTEB: XCHG ;TISK TEXTU Z BASICU
MOV E,C ;PRAMETRY PREDANY V DE - ODKUD
JMP WRITE ;A DELKA V C
SK08: LHLD P160 ;MRTVY KOD
MOV E,H ;MRTVY KOD
INX H ;MRTVY KOD
INX H ;MRTVY KOD
MOV A,M ;MRTVY KOD
INX H ;MRTVY KOD
MOV H,M ;MRTVY KOD
MOV L,A ;MRTVY KOD
WRITE: XRA A
STA COUNZ
WRIT1: MOV A,E
ORA A ;JE-LI DELKA NULOVA
RZ ;VRAT SE
LDA COUNZ
ORA A ;NENI-LI 1. ZNAK
JNZ WRIT3 ;SKOC
MOV A,M ;JE TO PRVNI ZNAK
ORA A ;TESTUJ JE-LI 0
JZ WRIT2 ;JE-LI TAK SKOC
MOV A,M ;NENI, JDI JEJ VYTISKNOUT
CALL ZNAK
SK19: JMP WRCON
WRIT2: INR A
STA COUNZ
CALL BS08
WRIT3: MOV A,M
CALL ZNAK4
MOV A,M
ORA A
JP WRCON
XRA A
STA COUNZ
CALL ZNAK3
WRCON: INX H ;DALSI POZICE ZNAKU
DCR E ;ZBIVAJICI POZET
JMP WRIT1 ;A ZNOVU
BS08: PUSH H ;NENI-LI NASTAVEN BS
LXI H,ZBS ;NA NULU NEDELA NIC
XRA A
CMP M
MOV M,A
JNZ BSNA
LHLD NOPX ;JINAK NASTAVI TISK ZNAKU
SHLD PREX ;NA NOVOU POZICI
LHLD NOPY
SHLD PREY
BSNA: POP H
RET
ZNAK: PUSH H
LXI H,ZBS
CPI 8
JNZ NOBS
MOV M,A ;MA-LI KOD $08
POP H ;POZE JEJ ULOZ
RET ;A RETURN
NOBS: ANI 7FH ;POZE 7 BITU
MOV C,A
CALL BS08 ;VYHODNOT BYL-LI KOD $08
LDA REZIM
ORA A
JNZ NODIA ;SKOC PRI ASCII REZIMU
MOV A,C
CPI 7BH
JC NODIA ;SKOC NENI-LI TO DIAKR ZNAK
ADI 5 ;ZVIS NA DIAKR. ZNAMENKA
MOV C,A
INR M
NODIA: MOV A,C ;ZNAK DO A
CPI 20H ;JE LI MENSI NEZ 20H
JC ZNAK2 ;SKOC
ANI 0F8H ;NE NULUJ 3 NEJNIZSI BITY
RAR ;VYDEL 2
RAR ; 4
ADI 0F8H ;ODECTI 3
ADI LOW TABSK;+ NIZSI BYTE ADRESY TAB
MOV L,A ;DO L
MVI A,0
ACI HIGH TABSK
MOV H,A ;DO H VYSSI BYTE TABULKY
MOV A,M
INX H
MOV H,M
MOV L,A ;DO HL ADRESU GENERATORU
MOV A,C
ANI 7 ;POUZE 3 NEJNIZSI BITY
MOV C,A
JZ VYZN ;JSOU-JI 0 SKOC
SKZN: MOV A,M ;NEJSOU
ORA A
INX H
JP SKZN ;TESTUJ NEJVISSI BIT
DCR C
JNZ SKZN ;SKOK NA ZNAK PODLE NICH
VYZN: MVI A,8 ;ZNAK V CG VYBRAN
CALL ZNAK4
ZNAK1: MOV A,M
CALL ZNAK4
MOV A,M
INX H
ORA A
JP ZNAK1
ZNAK2: POP H
ZNAK3: PUSH H
LDA WIDE
RLC
RAL
ADI 0F6H
CMA
MVI C,0
CALL ZNAK5
POP H
RET
ZNAK4: MOV C,A
ANI 7
ZNAK5: PUSH H
PUSH D
PUSH PSW
LHLD SIXX
XCHG
LHLD PREX
CALL ZNAK8
XCHG
MOV A,C
ANI 38H
RAR
RAR
RAR
LXI H,ZBS
ADD M
MOV B,A
LHLD SIYX
XCHG
CALL ZNAK8
POP PSW
PUSH H
LHLD SIXY
XCHG
LHLD PREY
CALL ZNAK8
MOV A,B
XCHG
LHLD SIYY
XCHG
CALL ZNAK8
PUSH H
MOV A,C
ANI 40H
JZ ZNAK6
LHLD NOPX
XCHG
LHLD NOPY
MOV B,H
MOV C,L
LDA SPEN
ORA A
CZ MOVA
POP B
POP D
CALL VECTA
JMP ZNAK7
ZNAK6: CALL PEN0
POP H
SHLD NOPY
POP H
SHLD NOPX
ZNAK7: POP D
POP H
RET
ZNAK8: INR E
DCR E
RZ
PUSH H
LXI H,0
ZNAK9: DCR A
JM ZNAK0
DAD D
JMP ZNAK9
ZNAK0: POP D
DAD D
RET
;PROVED KROK S MOTORY
ELEM: LHLD SMOT ;OKAMZITY STAV MOTORU
MOV H,A
ADD L ;PRICTI KROK K MOTORU
ANI 0FH ;SPODNI BITY MOTORU
MOV E,A ;DO E
MOV A,H ;DRUHY MOTOR
ANI 0F0H ;VYSSI BITY
ADD L ;PRICTI KROK
ANI 0F0H ;OPET POUZE VYSSI BITY
ORA E ;SLOZ S E
STA SMOT ;ULOZ TO NA STAV MOTORU
XRA A
MOV H,A
LDA ACCE
RAR
MOV L,A ;HL = RYCHLOST SNIZENA NA 1/2
JMP NASTM
PEN0: LDA SPEN ;ZVEDNI PERO
DCR A
RNZ ;JE LI ZVEDNUTO VRAT SE
JMP NASTP
PEN1: LDA SPEN ;SPUST PERO
DCR A
RZ ;JE-LI UZ DOLE VRAT SE
MVI A,1
NASTP: STA SPEN ;ULOZ TO NA STAV PERA
LXI H,1F4H ;PAUZA PRO PERO
NASTM: PUSH H
LHLD SPEN
MOV A,H
ANI 0EH
ORA L
MOV L,A
MOV A,H
ANI 0E0H
RRC
ORA L
RRC
OUT PORT2 ;POSLI TO NA MOTORY
POP H
ZPOZ0: LDA SPED
ZPOZ1: DCR A
JNZ ZPOZ1
DCX H
MOV A,H
ORA L
JNZ ZPOZ0
RET
COPYB: MOV B,H
MOV C,L
JMP COPY2
COPY1: PUSH B
PUSH D
POP B
POP D
COPY2: PUSH B
PUSH D
CALL MOVA
LXI D,2F0H ;RAMECEK
LXI B,0
PUSH B
CALL VECTR
POP D
PUSH D
LXI B,0FD08H
CALL VECTR
LXI D,0FD10H
POP B
CALL VECTR
POP D
POP B
CALL VECTA
LXI D,12H ;POC.TISKU
LXI B,0FFDCH
CALL MOVR
CALL NSIZE
MVI A,1 ;NAST.ASCII
STA REZIM
LHLD STPX
XCHG
LXI H,VIRAM
DALZN: MOV A,M
ANI 020H ;PREKODOVANI AND->ASCII
MOV A,M
JNZ VYST
ORI 40H ;DOPL.BITU 6 NA ASCII
VYST: CALL ZNAK
MOV A,M ;TEST NA DVOJ.SIRKU ZN.
CMA
ANI 0C0H
JNZ NENI
MVI A,020H ;KOD MEZERY
CALL ZNAK
INX H
NENI: INX H
MOV A,L
ANI 03FH ;DALSI RADEK?
CPI 028H ;>27H=KONEC RADKU
JC DALZN
DALR: PUSH B
LXI B,18H
DAD B ;DALSI PAM.MISTO
POP B
PUSH H
PUSH D
LXI B,0FFE0H
LHLD NOPY
DAD B
MOV B,H
MOV C,L
CALL MOVA ;NA DALSI RADEK
POP D
POP H
MOV A,H ;TEST NA KONEC VIDEORAM
CPI KVRAM
JC DALZN
JMP NSIZE
ORG STAR1
TEST: LXI D,186H
LXI B,0FF10H
CALL ORG1 ;PROVED ORG NA POZICI X,Y
MVI A,0AH
STA SIXX
STA SIYY ;VELIKOST ZNAKU
ADD A
STA P185
XRA A
STA WIDE ;MEZERA
INR A
STA REZIM ;ASCII REZIM
MVI H,20H
TCON: MOV A,H ;SMICKA PRO TISK CELE TAB.
CALL ZNAK
INR H
MOV A,H
ANI 7
JNZ TCON ;DALSI ZNAK
PUSH H ;BYLA UZ RADKA
MOV H,D
MOV L,E
SHLD NOPX
LHLD NOPY ;POSUN NA DALSI
LXI B,0FF80H;RADEK
DAD B
SHLD NOPY
POP H
MOV A,H
ORA A
JP TCON
JMP NAST
ORG TABSK
DW TAB20,TAB28,TAB30,TAB38,TAB40
DW TAB48,TAB50,TAB58,TAB60,TAB68
DW TAB70,TAB78,TAB80
TAB20: DB 80H,3AH,5AH,0AH,0CAH,31H,7AH
DB 32H,0FBH,39H,49H,0BH,7BH,2CH,68H,18H,0DCH
DB 10H,53H,5CH,63H,61H,68H,71H
DB 74H,3AH,0CAH,7CH,39H,70H,69H
DB 72H,79H,1BH,52H,4BH,54H,0DBH
DB 0CH,68H,70H,79H,7AH,73H,6BH
DB 50H,49H,4AH,0DCH,3BH,0F2H
TAB28: DB 3BH,69H,59H,0CBH,39H,6BH,5BH
DB 0C9H,11H,73H,24H,60H,31H,0D3H
DB 20H,64H,32H,0D2H,12H,0C1H,20H
DB 0E4H,0AH,0CAH,0FCH
TAB30: DB 7CH,34H,54H,4BH,49H,50H,70H
DB 79H,7BH,0F4H,29H,7BH,0CBH,30H
DB 79H,7BH,74H,6CH,48H,0CCH,30H
DB 79H,7BH,74H,6CH,63H,5CH,54H
DB 4BH,49H,0D0H,0BH,7BH,58H,0DCH
DB 10H,49H,4BH,54H,5CH,63H,60H
DB 78H,0FCH,34H,7BH,79H,70H,50H
DB 49H,4BH,54H,5CH,63H,61H,0D8H,7CH,0F8H
TAB38: DB 09H,50H,58H,61H,63H,6CH,74H
DB 7BH,79H,70H,68H,61H,63H,5CH
DB 54H,4BH,0C9H,10H,49H,4BH,54H
DB 74H,7BH,79H,70H,68H,61H,63H
DB 0ECH,1AH,5AH,2AH,0EAH,01H,52H
DB 22H,0E2H,33H,61H,0D3H,28H,6CH
DB 18H,0DCH,31H,63H,0D1H,30H,79H
DB 7BH,74H,6CH,5AH,52H,0AH,0CAH
TAB40: DB 68H,71H,73H,6CH,54H,4BH,4AH
DB 51H,61H,6AH,63H,0CBH,7AH,4CH
DB 21H,0E3H,78H,7BH,74H,6CH,63H
DB 60H,63H,5CH,54H,4BH,0C8H,34H
DB 7BH,79H,70H,50H,49H,4BH,0D4H
DB 78H,7BH,74H,54H,4BH,0C8H,3CH
DB 78H,48H,4CH,20H,0E2H,78H,7CH,20H,0E2H
DB 34H,7BH,79H,70H,50H,49H,4BH,54H,5CH,0DAH
TAB48: DB 78H,3CH,4CH,20H,0E4H,09H,4BH,4AH
DB 7AH,79H,0FBH,10H,49H,4BH,54H
DB 0FCH,78H,3CH,60H,0CCH,38H,48H
DB 0CCH,78H,62H,7CH,0CCH,78H,4CH
DB 0FCH,09H,50H,70H,79H,7BH,74H,54H,4BH,0C9H
TAB50: DB 78H,7BH,74H,6CH,63H,0E0H,09H
DB 50H,70H,79H,7BH,74H,54H,4BH
DB 49H,1AH,0CCH,78H,7BH,74H,6CH
DB 63H,60H,0CCH,10H,49H,4BH,54H
DB 5CH,63H,61H,68H,70H,79H,7BH
DB 0F4H,38H,7CH,3AH,0CAH,38H,50H
DB 49H,4BH,54H,0FCH,38H,4AH,0FCH
DB 38H,49H,6AH,4BH,0FCH
TAB58: DB 7CH,38H,0CCH,38H,62H,7CH,22H
DB 0CAH,38H,7CH,48H,0CCH,3BH,79H
DB 49H,0CBH,38H,0CCH,39H,7BH,4BH
DB 0C9H,31H,7AH,0F3H,0H,0C4H
TAB60: DB 39H,0F2H,29H,6BH,64H,54H,4BH
DB 49H,50H,59H,5BH,54H,0CCH,78H
DB 28H,6BH,64H,54H,4BH,0C8H,2CH
DB 69H,60H,50H,49H,0CCH,3CH,4CH
DB 49H,50H,60H,69H,0ECH,18H,5CH
DB 64H,6BH,69H,60H,50H,49H,0CCH
DB 0AH,72H,7BH,7CH,21H,0E3H,00H
DB 43H,4CH,6CH,69H,60H,58H,51H,0D4H
TAB68: DB 78H,28H,6BH,64H,0CCH,09H,4BH
DB 4AH,6AH,69H,3AH,0FAH,01H,42H
DB 4BH,6BH,6AH,3BH,0FBH,78H,2CH
DB 58H,0CCH,09H,4BH,4AH,7AH,0F9H
DB 68H,60H,69H,62H,4AH,22H,6BH
DB 64H,0CCH,68H,60H,69H,6BH,64H
DB 0CCH,09H,50H,60H,69H,6BH,64H,54H,4BH,0C9H
TAB70: DB 00H,68H,6BH,64H,5CH,53H,0D0H
DB 04H,6CH,69H,60H,58H,51H,0D4H
DB 09H,69H,61H,6AH,6BH,0E4H,4BH
DB 54H,5BH,59H,60H,69H,0ECH,0CH
DB 4BH,52H,7AH,29H,0EBH,28H,50H,49H
DB 4BH,54H,0ECH,28H,4AH,0ECH,28H
DB 49H,62H,4BH,0ECH
TAB78: DB 6CH,28H,0CCH,0H,43H,4CH,6CH
DB 28H,58H,51H,0D4H,28H,6CH,48H
DB 0CCH,0BH,52H,5AH,61H,6AH,72H
DB 0FBH,0AH,0FAH,09H,52H,5AH,63H
DB 6AH,72H,0F9H,20H,69H,5BH,0E4H,80H
TAB80: DB 32H,0FBH,2AH,71H,7AH,73H,0EAH
DB 39H,72H,0FBH,31H,7AH,0F3H,39H,79H,3BH,0FBH
.PHASE ZAZN ;BLOK PROMENICH V ZAZNAMNIKU
P160: DS 2
SIXX: DS 2 ;VELIKOST PISMA XX
SIXY: DS 2 ;VELIKOST PISMA XY
SIYX: DS 2 ;VELIKOST PISMA YX
SIYY: DS 2 ;VELIKOST PISMA YY
STPX: DS 2 ;OKAMZITA POLOHA PERA X
STPY: DS 2 ;OKAMZITA POLOHA PERA Y
NOPX: DS 2 ;POLOHA PRISTIHO TISKU ZN. X
NOPY: DS 2 ;POLOHA PRISTIHO TISKU ZN. Y
WIDE: DS 1 ;DRUH MEZERY MEZI ZNAKY
REZIM: DS 1 ;REZIM DIAKRITICKY/ASCII
ZBS: DS 1 ;ZAZN+14H
COUNZ: DS 1 ;CITAC ZNAKU PRI F. WRITE
SPEN: DS 1 ;OKAMZITY STAV PERA
SMOT: DS 1 ;STAV KROKOVYCH MOTORKU
PREX: DS 2 ;SOUR. PREDCHOZIHO TISKU X
PREY: DS 2 ;SOUR. PREDCHOZIHO TISKU Y
SPED: DS 1 ;AKTUALNI RICHLOST POSUVU
ACCE: DS 1 ;RICHLOST PRI ROZBEHU
DIRE: DS 1 ;SMER DO OS Y A X
DIR1: DS 1 ;
DIFF: DS 2 ;ROZDIL SOUR. ZADANE A SKUT.
DS 3
P185: DS 2 ;ZAZN + 25H
.DEPHASE
END
ÚVOD | Novinky | 8 Bitů | Příslušenství | Drobnosti | TTL | Kontakt
SAPI-1 | ONDRA | PMI-80 | PMD-85 | klony PMD-85 | klony SM50/40 | PETR | PLAN-80A | IQ151 | TNS | FK-1 | HVĚZDA
ZPS | Technické prostředky | Programové vybavení | Dokumentace